Après la technologie Ethernet étudiée au chapitre R3‑III , la technologie Wi‑Fi W (acronyme de wireless fidelity – étonnamment inspiré de l'acronyme Hi‑Fi du domaine audio‑phonique) apporte une excellente alternative aux liaisons filaires pour implémenter les couches liaison et physique dans les réseaux locaux à pile de protocoles TCP/IP. Basée sur les ondes électromagnétiques, elle offre des débits inférieurs et une moindre fiabilité que la technologie Ethernet, mais procure l'avantage décisif de la mobilité des hôtes.

Depuis le développement massif des terminaux mobiles (ordinateurs portables, smartphones, etc.) amorcé au début des années 2000, la technologie Wi‑Fi est maintenant très répandue, tant dans les réseaux publics (gares, centres commerciaux, cafés et restaurants…) que privés, qu'ils soient domestiques ou professionnels (et même industriels). On parle de réseaux locaux sans‑fil ou WLAN  – pour wireless local area network.

Précisons toutefois que :

• la technologie Wi‑Fi n'est pas la seule pour implémenter ce type de réseaux ; en particulier, on peut mettre en place un WLAN avec des protocoles de téléphonie mobile ou de domotique ;
• il faut ne pas confondre le sigle WLAN avec WAN (lequel signifie wide area network – cf. chap R1‑II ).

La technologie Wi‑Fi présente des points communs avec Ethernet. En premier lieu, elle est spécifiée par une famille de normes IEEE 802. Plus précisément, il s'agit des normes 802.11 dites normes Wi‑Fi qui, comme les normes 802.3 d'Ethernet (cf. chap. R3‑IV ), couvrent :

la sous‑couche MAC (medium access control) où elle reprend la notion d'adresse physique dite MAC ;

la couche physique, mais bien évidemment, avec des solutions de codage et modulation adaptées au medium de transmission qu'est le champ électromagnétique ambiant.

En revanche, du fait qu'elle repose sur un médium partagé, la technologie Wi‑Fi soulève des problématiques spécifiques, notamment en termes de sécurité et fiabilité. Et ces problématiques sont essentiellement gérées au niveau logiciel.

Objectif du chapitre : découverte de la technologie Wi‑Fi.

Technologie Wi‑Fi  –  Généralités

Historique et évolution

Aujourd'hui, la Wi‑Fi Alliance W compte plusieurs centaines de membres. Elle joue un rôle déterminant :

• dans la certification des équipements opérant la technologie Wi‑Fi ;
• dans l'évolution des normes Wi‑Fi en collaboration avec l'IEEE.

Notions de station et de point d'accès

En complément de la notion d'access point, il existe également celle de software enabled access point W – abrégé softAP. Ce terme désigne une machine qui n'est pas conçue pour cela mais qui remplit le rôle d'AP grâce à un composant logiciel.

C'est typiquement le cas d'un smartphone qui partage une connexion à l'Internet (4G) avec d'autres appareils – smartphones, PC portables, etc. – en créant un réseau Wi‑Fi autour de lui.

Dans la vie courante, on parle de hotspot W pour désigner un lieu, public ou privé, où un réseau Wi‑Fi avec un accès à l'Internet est mis à disposition d'usagers – typiquement, dans une gare, un aéroport, un café, etc.

La porté des ondes Wi‑Fi étant limitée, un hotstop mis en œuvre sur une surface étendue nécessite l'installation de plusieurs points d'accès.

Modes de liaison

Identifiant SSID

Avec la technologie Wi‑Fi, du fait que l'on utilise un médium de transmission commun et localement ubiquitaire (il est partout), on est confronté à la problématique essentielle du contrôle d'accès au réseau. En particulier, il n'est pas rare que plusieurs WLAN coexistent dans un espace donné. Il faut donc être en mesure d'identifier chaque réseau pour que les connexions et échanges de données ne s'entremêlent pas.

En règle générale, un SSID est associé à une clef de sécurité – ou mot de passe. Cet aspect sera abordé plus loin, dans le cadre des aspects logiciels .

Technologie Wi‑Fi  –  Aspects matériels

Rappels sur les ondes électromagnétiques

Une onde électromagnétique W est une variation périodique du champ électromagnétique ambiant – cf. la représentation vectorielle académique ci‑contre avec le champ électrique représenté en rouge et le champ magnétique en bleu, synchronisés.

Se propageant de façon transversale W et à la vitesse de la lumière – notée c – dans le milieu considéré, une onde électromagnétique est caractérisée par :

• son amplitude – en général, on retient la valeur maximale E₀ du champ électrique ;
• sa longueur d'onde notée λ, sa fréquence notée f et sa période notée T, qui vérifient les relations λ = c / f = c.T.

Application à la transmission de données

La figure ci‑dessous rappelle le spectre général W des ondes électromagnétiques avec leur désignation par gammes de longueurs d'onde.

Dans le contexte de la transmission de données par ondes électromagnétiques, pour le choix de la longueur d'onde, on est confronté à dilemme :

• plus la fréquence d'un onde est élevée – donc plus la longueur d'onde est courte – meilleur est le débit (fondamentalement, un débit est une fréquence) ;
• mais inversement, plus la longueur d'onde est courte, plus l'onde est énergétique – c'est‑à‑dire capable d'interactions avec les particules qu'elle rencontre – et donc, moindre est sa portée dans un milieu matériel.

Notion de canal Wi‑Fi

Pour optimiser les débits de transmissions, les deux bandes Wi‑Fi sont chacune divisées en une série de sous‑bandes appelées canaux Wi‑Fi W, avec ou sans chevauchement selon la bande.

Tout canal Wi‑Fi est défini par sa fréquence médiane et sa largeur – laquelle est exploitée pour la modulation des signaux. Pour simplifier l'identification, ils sont numérotés.

La bande 2,4 GHz se divise en 14 canaux chevauchants de largeur 22 MHz chacun, avec une distance de 5 MHz entre les fréquences médianes respectives de deux canaux voisins. Ils sont numérotés de 1 à 14.

Parmi ces canaux, il est possible d'en sélectionner 3 sans chevauchement – par exemple, les canaux nº 1, 6 et 11.

La bande 5 GHz se divise en 22 canaux non chevauchants de largeur 20 MHz chacun, avec une distance de 20 MHz entre les fréquences médianes respectives de deux canaux voisins. Ils sont numérotés de 4 en 4 :

• de 32 à 68 (donc 32, 36, 40…) sur la sous‑bande de 5,150 à 5,350 GHz ;
• de 96 à 140 (donc 96, 100, 104…) sur la sous‑bande de 5,470 à 5,850 GHz.

Force d'un signal Wi‑Fi

Pour mémoire, sur l'échelle des décibels, une augmentation de +3 dB exprime un doublement de la puissance du signal.

Dans le cas des réseaux Wi‑Fi, les puissances mises en jeu sont les plus faibles possibles pour ne pas rendre les signaux nocifs (à forte puissance, les micro‑ondes sont utilisées pour cuire les aliments). Les valeurs s'échelonnent de −30 dBm (excellente réception) à −90 dBm (connexion quasi‑impossible).

Interface réseau Wi‑Fi

Routeurs Wi‑Fi

Comme déjà mentionné au chap. R3‑III , un routeur Wi‑Fi comporte en général (cf. la face arrière du Cisco RV215W en photo ci‑dessous) :

• une multi‑port Ethernet étiqueté « LAN » ; il constitue un switch procurant quelques connexions filaires associée au WLAN que le routeur a pour fonction principale de mettre en œuvre ;
• un port Ethernet étiqueté « WAN » qui sert à raccorder le routeur dans un LAN, avec en principe un accès vers un WAN – l'Internet.

Points d'accès Wi‑Fi (équipement)

Moins cher qu'un routeur, un point d'accès peut constituer une solution satisfaisante pour étendre un WLAN avec une administration centralisée. C'est la solution privilégiée dans les grands bâtiments de bureau, les espaces publics connectés, les établissements scolaires, etc.

Comme pour les routeurs, il existe une grande variété de modèles adaptés en fonction des besoins domestiques ou professionnels. L'absence d'antenne apparente diminue un peu la portée mais présente une meilleure robustesse aux dégradations dans les environnements publics (cf. quelques exemples en photo ci‑dessous).

Répéteurs et ponts Wi‑Fi

Répéteurs Wi‑Fi

Rappelons (cf. supra ) qu'un répéteur Wi‑Fi n'est pas un point d'accès mais un équipement qui permet d'étendre la portée d'un WAP déjà installé.

En termes de mise en œuvre des protocoles réseau, un répéteur doit donc être considéré comme passif, il ne constitue pas un nœud du réseau (cf. chap. R1‑II ).

Matériellement, un tel équipement dispose simplement d'une alimentation électrique, d'une ou plusieurs antennes Wi‑Fi, d'une carte électronique d'amplification et de répétition des signaux qu'il reçoit des stations Wi‑Fi qu'il dessert (les machines qui se connectent à travers lui) et du WAP dont il étend la portée.

Les différents modèles de répéteurs Wi‑Fi vendus dans le commerce se distinguent principalement par leur portée et les normes de protection qu'ils respectent en vue de leur usage pour l'intérieur, l'extérieur, les locaux publics ou privés, etc. – cf. quelques exemples en photo ci‑dessous.

Les modèles d'intérieur qualifiés dans le commerce de répéteurs Wi‑Fi présentent diverses caractéristiques qui peuvent être sujettes à des confusions.

• La prise électrique en façade sert simplement de prolongement à la prise murale sur laquelle l'appareil est branché, afin de ne pas en monopoliser l'usage.
• Un éventuel port Ethernet peut être présent permettre à des clients de se raccorder localement au réseau qu'il étend par connexion filaire plutôt que Wi‑Fi. Mais ce n'est pas un port « WAN » comme sur un équipement de type point d'accès.
• Certains modèles sont en fait polyvalents et peuvent faire fonction de point d'accès, voire même de routeur Wi‑Fi (cf. le modèle d'intérieur en photo tout à droite dans le cadre de gauche ci‑dessus).

Ponts Wi‑Fi

Techniquement, un pont Wi‑Fi est un équipement qui agit comme un puissant répéteur. Il est essentiellement constitué d'une paire d'antennes à installer en vis‑à‑vis en extérieur pour créer une liaison sans‑fil pour déployer entre deux bâtiments (cf. le modèle en photo ci‑contre).

Technologie Wi‑Fi  –  Aspects logiciels

Comme cela a été souligné à plusieurs reprises dans ce chapitre, la technologie Wi‑Fi repose physiquement sur un médium partagé, le champ électromagnétique ambiant. Se posent donc des problématiques de :

• fiabilité – le fait, par exemple, qu'une transmission ne soit pas perturbée par une autre ;
• sécurité – le fait que l'accès au réseau puisse être contrôlé (et non pas accessible à tous) ou qu'un tiers ne puisse pas lire les échanges de donnée entre une station et un point d'accès

Tous ces aspects sont pris en charge au niveau logiciel.

Identification des interfaces réseau Wi‑Fi

On rappelle (cf. introduction) que la technologie Wi‑Fi est spécifiée par les normes 802.11 qui couvrent notamment la sous‑couche MAC.

Toute interface réseau Wi‑Fi est donc identifiée par son adresse MAC – à savoir un identifiant numérique codé sur 48 bits – exactement comme une interface réseau Ethernet (cf. chap. R1‑III ).

Protocoles sécurisés de connexion

Dans un LAN filaire, il est incontournable d'avoir physiquement accès à une prise réseau pour pouvoir y raccorder une machine (sans considérer les éventuelles possibilités de connexion distante via une passerelle). Si le réseau est déployé dans des locaux privés, il est donc a priori inaccessible à toute machine externe aux locaux.

Au contraire, dans un WLAN, n'importe quelle machine située à l'extérieur des locaux mais dans la portée d'un WAP pourrait a priori se connecter au réseau, car les murs usuels ne sont pas totalement imperméables aux ondes Wi‑Fi (ce qui est d'ailleurs un atout de cette technologie). C'est pourquoi un contrôle d'accès est vivement recommandé.

Que le SSID soit diffusé ou non, l'accès à un WLAN engage la responsabilité du (des) administrateur(s) du réseau dans lequel le WLAN est intégré. C'est pourquoi il est fortement recommandé de limiter son accès par un protocole d'authentification avec un mot de passe.

Connexion par protocole chiffré

Afin de satisfaire aux exigences de confidentialité, une connexion Wi‑Fi obéit toujours à un protocole avec chiffrement des données dès le début de la connexion.

Sinon, n'importe quelle communication entre un client et un WAP peut être interceptée par une machine tierce à l'aide d'un logiciel dédié (sniffeur Wi‑Fi).

Paramétrage d'une interface Wi‑Fi

Cas d'une carte Raspberry‑Pi

L'utilitaire de gravage Raspberry‑Pi Imager a déjà été présenté dans le sujet de TP R2‑2 . Pour mémoire, on accède aux paramètres avancés lors de la phase de personnalisation du système, en choisissant l'option Modifier réglages. Dans l'onglet Général, il suffit alors de cocher la case Configurer le Wi‑Fi et renseigner :

• le SSID (cf. supra ) ;
• le mot de passe, c'est‑à‑dire la clef de sécurité ;
• le « pays » Wi‑Fi parmi les options possibles données dans un menu déroulant.
Ce paramètre permet au système d'optimiser automatiquement les réglages de l'interface – fréquence, canal, puissance d'émission – en fonction de la réglementation du pays dans lequel la carte est supposée fonctionner.

L'utilitaire de configuration semi‑graphique raspi-config se lance dans un terminal de commandes en lignes – donc, y compris via une connexion ssh – en tapant tout simplement :

sudo raspi-config

Le terminal passe alors en mode semi‑graphique avec des menus déroulants qu'on peut notamment faire défiler avec les touches « flèches » du clavier ←↑↓→, sachant que dans un menu :

• la validation du choix d'item en surbrillance peut s'effectuer :
• soit directement en tapant ENTRÉE ↵ ;
• soit en appuyant sur → pour activer <Select> puis sur ENTRÉE ↵ ;
• la sortie s'effectue sur  → autant de fois que nécessaire pour activer <Finish> puis sur ENTRÉE ↵.

À partir du menu principal, il suffit de choisir  1 System Options puis S1 Wireless LAN. On est alors invité à saisir successivement le SSID et le mot de passe (passphrase) qui est masqué, sachant qu'on peut éventuellement procéder par copier‑coller depuis un éditeur de texte externe pour éviter toute erreur sur la saisie du mot de passe.

Remarque : la commande sudo nmtui met aussi en œuvre un outil semi‑graphique tellement intuitif qu'il ne nécessite pas d'explications pour être utilisé avec succès par un débutant. De plus, cet outil est plus polyvalent que raspi-config car il permet aussi de configurer la connexion par liaison Ethernet.

Protocole de communication à évitement de collisions

Trames Wi‑Fi

Les trames Wi‑Fi adoptent une structure globale similaire à celles de la technologie Ethernet W. Mais des spécificités existent, notamment en fonction des techniques de modulation et de multiplexage adoptées.

Techniques de modulation et multiplexage

Protocole de routage dans les réseaux maillés

OLSR W (optimized link state routing protocol)

Mise en œuvre sur carte à microcontrôleur

Les modules de bibliothèque ESP8266Wifi

La mise en œuvre des fonctionnalités Wi‑Fi sur une carte à microcontrôleur ESP8266 requiert la directive d'inclusion du fichier d'en‑tête principal :
#include <ESP8266WiFi.h>
sachant que ce fichier :

• comporte lui‑même 12 directives d'inclusion, en particulier celle du fichier d'en‑tête Arduino IPAddress.h (cf. chap. R1‑III ) ;
• déclare l'objet WiFi par lequel on peut appeler les méthodes publiques du module de bibliothèque ; cette instance n'a donc pas besoin d'être déclarée dans le programme utilisateur (à l'instar de l'objet Serial pour la mise en œuvre de moniteur série – cf. chap. C3‑X C).

Le module offre de très nombreuses méthodes publiques associées à l'objet WiFi, qu'il ne serait pas raisonnable de détailler en intégralité dans ce cours. On ne va donc présenter que les plus usuelles. En tout premier lieu, on trouve dans le fichier d'en‑tête ESP8266WiFiGeneric.h G diverses méthodes génériques, la plus importante étant la suivante :

• WiFi.mode  code le choix du mode de fonctionnement de la carte programmée.
• Elle prend pour seul argument une valeur de type énuméré WiFiMode_t parmi les 4 constantes déclarées WIFI_OFF, WIFI_STA (mode station), WIFI_AP (mode access point) et WIFI_AP_STA (mode mixte).
• Elle retourne une valeur booléenne qui exprime la faisabilité du mode sur la carte.
• WiFi.channel , sans argument, retourne le canal Wi‑Fi adopté.

Une bonne partie des autres méthodes sont spécifiques aux modes respectifs station et access point.

Mise en œuvre d'une carte ESP8266 en mode station

Pour la mise en œuvre d'une station et tout particulièrement sa connexion à un WLAN préexistant, on dispose des méthodes suivantes, toutes déclarées dans le fichier d'en‑tête ESP8266WiFiSTA.h G :

• WiFi.config  code l'attribution d'une configuration IP statique choisie pour la carte programmée en mode station.
• Elle admet de 3 à 5 arguments de classe IPAddress qui codent respectivement l'adresse IP, la passerelle par défaut, le masque de sous‑réseau et, optionnellement, les deux adresses de résolveur DNS.
• Elle retourne une valeur booléenne qui exprime la compatibilité de la configuration avec le mode choisi pour la carte.
Remarque. Sans appel de la méthode config dans le programme utilisateur, la carte adopte par défaut une configuration IP dynamique (ce qui requiert l'existence du service DHCP sur le réseau – cf. chap. R2‑II ).
• WiFi.begin  code la commande de connexion à un WLAN avec le mode et la configuration préalablement codés.
• Elle possède plusieurs variantes d'appel (surcharges), la plus usuelle étant de la forme :
  WiFi.begin(SSID, password)
  où SSID et password sont les identifiants de connexion au WLAN (cf. supra ) ;
• Elle retourne une valeur de type énuméré wl_status_t déclaré dans le fichier d'en‑tête wl_definitions.h G.
Remarque. La méthode begin n'a pas besoin d'être réitérée en cas d'échec. De plus, en cas de déconnexion, le socket réseau met en œuvre une procédure automatique de reconnexion.
• WiFi.status , sans argument, retourne le statut courant de la connexion à un WLAN, exprimé par une valeur de type énuméré wl_status_t (cf. ci‑dessus).
Les valeurs exprimant que la connexion ou la déconnexion est effective sont respectivement codées WL_CONNECTED et  WL_DISCONNECTED(les autres valeurs servent à faire du diagnostic en cas d'échec).
• WiFi.isConnected  est une alternative plus simple et lisible que status pour déterminer si la carte est connectée à un WLAN. Elle est sans argument et retourne une valeur de type bool.
• WiFi.disconnect  code la déconnexion de la carte.
• Elle admet 1 ou 2 arguments optionnels de type bool pour provoquer respectivement :
1. le retour dans le mode WIFI_OFF ;
2. l'effacement en mémoire des identifiants de connexion (SSID et PSWD).
• Elle retourne une valeur de type bool qui exprime le succès ou non de la déconnexion.

Dans le fichier d'en‑tête ESP8266WiFiSTA.h G sont également déclarées toute une série de méthodes pour récupérer les paramètres de connexion (un fois que cette dernière est établie)  :

• WiFi.localIP, WiFi.subnetMask, WiFi.gatewayIP, WiFi.dnsIP retournent respectivement les adresses IP de la configuration de la carte (cf. chap. R1‑III ), dans la classe IPAddress.
Ces méthodes ne prennent pas d'argument sauf dnsIP qui admet un argument de type uint8_t pour indiquer le numéro d'ordre du résolveur DNS, avec pour seules valeurs possibles 0 pour le primaire (valeur par défaut) et 1 pour le secondaire (cf. chap. R2‑I ).
• WiFi.macAddress, sans argument, retourne l'adresse MAC de la carte sous la forme d'un chaîne de caractère de la classe String.
Il existe également une surcharge de cette méthode qui retourne l'adresse MAC sous la forme d'un tableau (également passé comme argument transmis par adresse).
• WiFi.RSSI, sans argument, retourne la force du signal Wi‑Fi reçu (cf. supra ) exprimée en dBm par une valeur de type int32_t.

Le programme de démonstration ci‑après est codé pour connecter à volonté une carte de développement NodeMCU à microcontrôleur ESP8266 à un point d'accès dans un WLAN et afficher les éléments de connexion sur le moniteur série. Il ne nécessite aucun accessoire car il exploite le bouton intégré FLASH de la carte et la led intégrée au module ESP‑12 (cf. chap. C1‑III ).

Pour plus de confidentialité, les identifiants de connexion au point d'accès sont déportés dans un fichier d'en‑tête connectionID.h, comme ci‑dessous (valeurs ici masquées) :

/***** WLAN connection IDs *****/
const char * SSID = "xxxxx";
const char * PSWD = "???????????????????????????????????????";

Le programme est structuré avec 3 fonctions auxiliaires :

• buttonPushed qui détecte un appui sur le bouton FLASH ;
• connectToAP qui effectue la connexion de la carte au point d'accès ;
• disconnectFromAP qui effectue la déconnexion de la carte.

Les appuis sur le bouton commandent la connexion/déconnexion de la carte. Lorsque la connexion est établie, la led intégrée brille proportionnellement à la force du signal (RSSI). Elle s'éteint en cas de déconnexion.

#include <ESP8266WiFi.h>

#include "connectionID.h" // -> Access point SSID & PSWD

const uint8_t LED_PIN = 2;    // ESP-12 module builtin led (negative logic)
const uint8_t BUTTON_PIN = 0; // builtin button "flash"

void setup()
{
  Serial.begin(115200);
  Serial.flush();
  Serial.println();

  pinMode(LED_PIN, OUTPUT);
  pinMode(BUTTON_PIN, INPUT_PULLUP);
}

void loop()
{
  if (buttonPushed()) {
    WiFi.isConnected() ? disconnectFromAP() : connectToAP();
  }

  if (WiFi.isConnected()) {
    analogWrite(LED_PIN, map(WiFi.RSSI(), -80, -30, 255, 0)); // negative logic
  }
  else {
    digitalWrite(LED_PIN, !LOW); // negative logic
  }
}

void connectToAP()
{
  WiFi.mode(WIFI_STA);      // station mode
  WiFi.begin(SSID, PSWD);   // no config, DHCP mode     
  Serial.print("Connection in process");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println();

  Serial.printf("Connected to WLAN %s\n", WiFi.SSID().c_str());
  Serial.printf("Channel %d\tSignal strength = %d dBm\n", WiFi.channel(), WiFi.RSSI()); 
  Serial.println("IPv4    = " + WiFi.localIP().toString());
  Serial.println("Mask    = " + WiFi.subnetMask().toString());
  Serial.println("Gateway = " + WiFi.gatewayIP().toString());
  Serial.println("DNS1    = " + WiFi.dnsIP(0).toString());
  Serial.println("DNS2    = " + WiFi.dnsIP(1).toString());
  Serial.flush();
}

void disconnectFromAP()
{
  WiFi.disconnect(true);
  Serial.print("Disconnection ");
  while (WiFi.status() != WL_DISCONNECTED) {
    delay(500);
  }
  Serial.println(" complete.");
  Serial.println();
  Serial.flush();
}

bool buttonPushed()
{
  static bool previousButtonLevel = HIGH; // negative logic
  static bool currentButtonLevel  = HIGH;  
  previousButtonLevel = currentButtonLevel;
  currentButtonLevel  = digitalRead(BUTTON_PIN); 
  return (currentButtonLevel == LOW && previousButtonLevel == HIGH); // falling edge
}

Lors d'une exécution du programme, si par exemple l'utilisateur appuie 2 fois sur le bouton FLASH à une minute d'intervalle, on obtient sur le moniteur série typiquement un affichage comme ci‑dessous :

Connection in process...........
Connected to WLAN xxxxx
Channel 11      Signal strength = -50 dBm
IPv4    = 192.168.1.18
Mask    = 255.255.255.0
Gateway = 192.168.1.1
DNS1    = 8.8.8.8
DNS2    = 8.8.4.4
Disconnection from xxxxx complete.

Remarque. Dans la bibliothèque développée pour les cartes à microcontrôleur ESP8266, il existe une implémentation de la fonction printf pour l'objet Serial.

• Elle est déclarée dans le fichier d'en‑tête Print.h G.
• Elle adopte une syntaxe similaire à celle de la fonction printf de la bibliothèque standard du langage C (déclarée dans le fichier d'en‑tête stdio.h).

#include <ESP8266WiFi.h>

#include "connectionID.h" // -> Access point SSID & PSWD

const uint8_t LED_PIN = 2;    // ESP-12 module builtin led (negative logic)
const uint8_t BUTTON_PIN = 0; // builtin button "flash"

void setup()
{
  Serial.begin(115200);
  Serial.flush();
  Serial.println();

  pinMode(LED_PIN, OUTPUT);
  pinMode(BUTTON_PIN, INPUT_PULLUP);

  static WiFiEventHandler onConnectionHandler    = WiFi.onStationModeConnected(onConnected);
  static WiFiEventHandler onGotIPhandler         = WiFi.onStationModeGotIP(onGotIP);
  static WiFiEventHandler onDisconnectionHandler = WiFi.onStationModeDisconnected(onDisconnected);
}

void loop()
{
  if (buttonPushed()) {
    WiFi.isConnected() ? disconnectFromAP() : connectToAP();
  }

  if (WiFi.isConnected()) {
    analogWrite(LED_PIN, map(WiFi.RSSI(), -80, -30, 255, 0)); // negative logic
  }
  else {
    digitalWrite(LED_PIN, !LOW); // negative logic
  }
  delay(5);
}

void connectToAP()
{
  WiFi.mode(WIFI_STA); // station mode
  WiFi.begin(SSID, PSWD);
  Serial.print("Connection in process...");
}

// callback on connection
void onConnected(const WiFiEventStationModeConnected & event)
{
  Serial.printf("\nConnected to WLAN %s\n", event.ssid.c_str());
  Serial.printf("Channel %d\tSignal strength = %d dBm\n", event.channel, WiFi.RSSI()); 
  Serial.flush();
}

// callback on configuration
void onGotIP(const WiFiEventStationModeGotIP & event)
{
  Serial.println("IPv4    = " + event.ip.toString());
  Serial.println("Mask    = " + event.mask.toString());
  Serial.println("Gateway = " + event.gw.toString());
  Serial.println("DNS1    = " + WiFi.dnsIP(0).toString());
  Serial.println("DNS2    = " + WiFi.dnsIP(1).toString());
  Serial.flush();
}

void disconnectFromAP()
{
  WiFi.disconnect(true);
  Serial.print("Disconnection ");
}

// callback on disconnection
void onDisconnected(const WiFiEventStationModeDisconnected & event)
{
  Serial.printf("from %s complete\n", event.ssid.c_str());
  Serial.flush();
}

bool buttonPushed()
{
  static bool previousButtonLevel = HIGH; // negative logic
  static bool currentButtonLevel  = HIGH;  
  previousButtonLevel = currentButtonLevel;
  currentButtonLevel  = digitalRead(BUTTON_PIN); 
  return (currentButtonLevel == LOW && previousButtonLevel == HIGH); // falling edge
}

Mise en œuvre d'une carte ESP8266 en mode access point

La bibliothèque ESP8266WiFipermet la mise en œuvre d'un point d'accès sur une carte à microcontrôleur ESP8266. Avec des potentialités limitées comparativement à celles d'un routeur, il permet la connexion de jusqu'à 8 stations avec la prise en charge d'un service DHCP.

Pour cette mise en œuvre, on dispose des méthodes suivantes, toutes déclarées dans le fichier d'en‑tête ESP8266WiFiAP.h G :

• WiFi.softAP  code l'activation du point d'accès configuration IP statique choisie pour la carte programmée en mode station.
• Elle possède plusieurs variantes d'appel (surcharges), la plus usuelle étant de la forme :
  WiFi.softAP(SSID, password) où SSID et password sont les identifiants de connexion au point d'accès (cf. supra ) ;
• Elle retourne une valeur de type bool qui indique le succès de l'activation.
Dans la forme d'appel ci‑dessus, le paramètre password est optionnel. S'il est omis, le point d'accès est ouvert à toute connexion sans contrôle d'accès.
La méthode WiFi.softAP possède d'autres paramètres optionnels :
• channel, de type int, pour fixer le canal Wi‑Fi utilisé ;
• hidden, de type bool, pour cacher le SSID  ;
• max connection, de type int, pour limiter le nombre de stations prises en charge par le point d'accès (la valeur par défaut est 4, la valeur maximale 8).
• WiFi.softAPConfig  code la configuration IP du sous‑réseau mis en œuvre par le point d'accès.
• Elle admet de 3 arguments de classe IPAddress qui codent respectivement l'adresse IP du point d'accès, la passerelle par défaut et le masque de sous‑réseau.
Implicitement, les adresses des résolveurs DNS sont attribuées identiques à celle de la passerelle. Ce choix est motivé par le fait que la carte elle‑même n'a pas la capacité de mettre en œuvre cette fonctionnalité.
• Sa valeur de retour, de type bool, exprime le succès de la configuration.
Il est recommandé de configurer le point d'accès avec un réseau en /24 (typiquement, 192.168.x.0/24) et d'attribuer l'adresse 1 à la carte. En effet, le service DHCP sélectionne automatiquement une plage d'adresses dynamiques décalée de 99 par rapport à l'adresse de la carte – donc, commençant à l'adresse 100 si la carte a l'adresse 1, ce qui est « lisible ».
Si le programme utilisateur n'appelle pas la méthode WiFi.softAPConfig, alors le point d'accès adopte la configuration par défaut 192.168.4.1/24 et attribue aussi l'adresse 1 à la passerelle. La plage d'adresses dynamiques commence alors à l'adresse 2.
• WiFi.softAPIP , sans argument retourne l'adresse IP du point d'accès, de classe IPAddress.
Cette méthode peut être utilisée pour déterminer si le point d'accès est correctement activé.
• WiFi.softAPgetStationNum , sans argument retourne le nombre de stations connectées au point d'accès.
La bibliothèque ESP8266WiFi ne déclare pas de méthode pour récupérer les informations (hostname, adresse MAC, adresse IP) des stations connectées au point d'accès.
• WiFi.softAPdisconnect , code la désactivation du point d'accès.
• Elle prend un unique argument de type bool qui, s'il est passé à la valeur true, désactive aussi le mode access point.
• Sa valeur de retour, de type bool, exprime le succès de la désactivation.

Le programme de démonstration ci‑après est codé pour activer à volonté un point d'accès sur une carte de développement NodeMCU à microcontrôleur ESP8266. Comme pour l'exemple de démonstration de contrôle d'une connexion à un point d'accès (cf. supra ) :

• il exploite le bouton intégré FLASH et la led intégrée au module ESP‑12 ;
• il déporte les identifiants de connexion au point d'accès dans un fichier d'en‑tête connectionID.h ;
• Le programme est structuré avec 3 fonctions auxiliaires, ici :
• buttonPushed qui détecte un appui sur le bouton FLASH ;
• enableAP qui active le point d'accès ;
• disableAP qui désactive le point d'accès.

#include <ESP8266WiFi.h>

#include "connectionID.h" // -> Access point SSID & PSWD

const uint8_t LED_PIN = 2;    // ESP-12 module builtin led (negative logic)
const uint8_t BUTTON_PIN = 0; // builtin button "flash"

// AP subnet configuration 
IPAddress ap_localIP (192, 168, 10, 1);
IPAddress ap_gateway (192, 168, 10, 1);
IPAddress ap_subnet  (255, 255, 255,0);


void setup()
{
  Serial.begin(115200);
  Serial.flush();
  Serial.println();

  pinMode(LED_PIN, OUTPUT);
  pinMode(BUTTON_PIN, INPUT_PULLUP);
}

void loop()
{
  static int8_t previousStationNum = -1;
  if (buttonPushed()) {
    if (WiFi.softAPIP()) {
      disableAP();
      previousStationNum = -1;
    }
    else {
      enableAP();
    }
  }
  
  if (WiFi.softAPIP()) {
    digitalWrite(LED_PIN, !HIGH); // LED negative logic
    if (previousStationNum != WiFi.softAPgetStationNum()) {
      Serial.printf("Nb. of Nb. of stations connected: %d\n", WiFi.softAPgetStationNum());
      previousStationNum = WiFi.softAPgetStationNum();
    }
  }
  else {
    digitalWrite(LED_PIN, !LOW);  // LED negative logic
  }
}

bool buttonPushed()
{
  static bool previousButtonLevel = HIGH; // negative logic
  static bool currentButtonLevel  = HIGH;  
  previousButtonLevel = currentButtonLevel;
  currentButtonLevel  = digitalRead(BUTTON_PIN); 
  return (currentButtonLevel == LOW && previousButtonLevel == HIGH); // falling edge
}

void enableAP()
{
  WiFi.mode(WIFI_AP); // station mode
  if (WiFi.softAPConfig(ap_localIP, ap_gateway, ap_subnet)) {
    Serial.println("AP configured with:");
    Serial.println("IPv4    = " + ap_localIP.toString());
    Serial.println("Mask    = " + ap_subnet.toString());
    Serial.println("Gateway = " + ap_gateway.toString());
    Serial.flush();
  }
  else {
     Serial.println("AP configuration failed");
  }
  if (WiFi.softAP(SSID, PSWD, false)) {
    Serial.println("AP enabled");
  }
  else {
     Serial.println("AP enabling failed");
  }
}

void disableAP()
{
  if (WiFi.softAPdisconnect(true)) {
    Serial.println("AP disabled");
  }
  else {
    Serial.println("AP disabling failed");
  }
}

Lors d'une exécution du programme, si par exemple l'utilisateur :

1. active le point d'accès en appuyant une première fois sur le bouton FLASH de la carte,
2. se connecte au point d'accès avec son smartphone,
3. se déconnecte du point d'accès,
4. déactive le point d'accès en appuyant une deuxième fois sur le bouton FLASH de la carte,

alors on obtient sur le moniteur série un affichage comme ci‑dessous :

AP configured with:
IPv4    = 192.168.10.1
Mask    = 255.255.255.0
Gateway = 192.168.10.1
AP enabled
Nb. of stations connected: 0
Nb. of stations connected: 1
Nb. of stations connected: 0
AP disabled

Dans le fichier d'en‑tête ESP8266WiFiAP.h, on ne trouve malheureusement aucune méthode pour identifier une station connectée au point d'accès, par son nom d'hôte, son adresse IP ou son adresse MAC.

#include <ESP8266WiFi.h>

#include "connectionID.h" // -> Access point SSID & PSWD

const uint8_t LED_PIN = 2;    // ESP-12 module builtin led (negative logic)
const uint8_t BUTTON_PIN = 0; // builtin button "flash"

// AP subnet configuration 
IPAddress ap_localIP (192, 168,  10, 1);
IPAddress ap_gateway (192, 168,  10, 1);
IPAddress ap_subnet  (255, 255, 255, 0);


void setup()
{
  Serial.begin(115200);
  Serial.flush();
  Serial.println();

  pinMode(LED_PIN, OUTPUT);
  pinMode(BUTTON_PIN, INPUT_PULLUP);

  static WiFiEventHandler onSoftAPConnectedHandler    = WiFi.onSoftAPModeStationConnected(onStationConnected);
  static WiFiEventHandler onSoftAPDisconnectedHandler = WiFi.onSoftAPModeStationDisconnected(onStationDisconnected);
}

void loop()
{
  if (buttonPushed()) {
    WiFi.softAPIP() ? disableAP() : enableAP();
  }
  digitalWrite(LED_PIN, !WiFi.softAPIP()); // LED negative logic
}

bool buttonPushed()
{
  static bool previousButtonLevel = HIGH; // negative logic
  static bool currentButtonLevel  = HIGH;  
  previousButtonLevel = currentButtonLevel;
  currentButtonLevel  = digitalRead(BUTTON_PIN); 
  return (currentButtonLevel == LOW && previousButtonLevel == HIGH); // falling edge
}

void enableAP()
{
  WiFi.mode(WIFI_AP); // station mode
  if (WiFi.softAPConfig(ap_localIP, ap_gateway, ap_subnet)) {
    Serial.println("AP configured with:");
    Serial.println("IPv4    = " + ap_localIP.toString());
    Serial.println("Mask    = " + ap_subnet.toString());
    Serial.println("Gateway = " + ap_gateway.toString());
    Serial.flush();
  }
  else {
     Serial.println("AP configuration failed");
  }
  if (WiFi.softAP(SSID, PSWD, false)) {
    Serial.println("AP enabled");
  }
  else {
     Serial.println("AP enabling failed");
  }
}

void disableAP()
{
  if (WiFi.softAPdisconnect(true)) {
    Serial.println("AP disabled");
  }
  else {
    Serial.println("AP disabling failed");
  }
}

// callback on connection
void onStationConnected(const WiFiEventSoftAPModeStationConnected & event)
{
  Serial.printf("New station connected: id. %d, MAC ", event.aid);
  displayMACaddress(event.mac);
  Serial.printf("Nb. of stations connected: %d\n", WiFi.softAPgetStationNum());
}

// callback on disconnection
void onStationDisconnected(const WiFiEventSoftAPModeStationDisconnected & event)
{
  Serial.printf("Station disconnected:  id. %d, MAC ", event.aid);
  displayMACaddress(event.mac);
  Serial.printf("Nb. of stations connected: %d\n", WiFi.softAPgetStationNum());
}

void displayMACaddress(const uint8_t * mac)
{
  for (uint8_t byteRank = 0; byteRank <= 5; byteRank++) {
    Serial.print(mac[byteRank], HEX);
    byteRank < 5 ? Serial.print("-") : Serial.println();
  }
}

AP configured with:
IPv4    = 192.168.10.1
Mask    = 255.255.255.0
Gateway = 192.168.10.1
AP enabled
New station connected: id. 1, MAC XX-XX-XX-XX-XX-XX
Nb. of stations connected: 1
Station disconnected:  id. 1, MAC XX-XX-XX-XX-XX-XX
Nb. of stations connected: 0
AP disabled

Autres fonctionnalités du module de bibliothèque ESP8266WiFi

Scan des réseaux Wi‑Fi environnants

Un scan de réseaux Wi‑Fi consiste à détecter et lister les réseaux Wi‑Fi environnants d'un système. Sur une carte à microcontrôleur, une telle fonctionnalité peut être utile :

• en elle‑même – si c'est précisément le rôle qu'on assigne au programme utilisateur :
• ou pour apporter une souplesse de connexion au système (pour par exemple choisir tel ou tel réseau en fonction de la force du signal).

Les méthodes de scan  sont déclarées dans le fichier d'en‑tête ESP8266WiFiScan.h G.

• La plus utile est la méthode :
  WiFi.scanNetworksAsync(onComplete, show_hidden)
  qui lance un scan en tâche de fond avec :
• mémorisation des caractéristiques des réseaux détectés ;
• appel de la fonction de callback onComplete (premier argument) lorsque le scan est achevé ;
• repérage des réseaux cachés lorsque l'argument show_hidden est passé avec la valeur true.
• On dispose également de diverses méthodes pour récupérer les caractéristiques des réseaux scannées, toutes prenant un argument numérique n qui spécifie le numéro d'ordre du réseau scanné parmi tous ceux détectés. En particulier, on a :
• WiFi.SSID(n) retourne le SSID du réseau nº n scanné.
• WiFi.channel(n) retourne le canal Wi‑Fi exploité par le réseau nº n scanné.
• WiFi.encryptionType(n) pour retourne le chiffrement utilisé par le réseau nº n scanné. La valeur retournée est du type énuméré wl_enc_type qui est déclaré dans le fichier d'en‑tête wl_definitions.h G.

#include <ESP8266WiFi.h>

const int BUTTON_PIN = 0; // builtin button "flash"

const char * encryption[] = {"?", "?", "WPA - TKIP", "?", "WPA2 - CCMP", "WEP",
                             "?", "NONE", "AUTO"};

void setup()
{
  Serial.begin(115200);
  Serial.println();

  WiFi.mode(WIFI_STA);
  WiFi.disconnect();
  delay(1000);
}

void loop()
{
  if (buttonPushed()) {
    WiFi.scanNetworksAsync(displayScan, true); // true -> hidden networks displayed
  }
}

// callback function called when scan completed
void displayScan(int networksFound)
{
  Serial.printf("%d networks found\n", networksFound);
  for (int n = 0; n < networksFound; n++) {
    Serial.printf("%2d: %30s ", n + 1, WiFi.SSID(n).c_str());
    Serial.printf("Ch: %2d (%d dBm) ", WiFi.channel(n), WiFi.RSSI(n));
    Serial.printf("%s %s\n", encryption[WiFi.encryptionType(n)], WiFi.isHidden(n) ? "(hidden)" : " ");
    Serial.flush();
  }
  Serial.println();
}

bool buttonPushed()
{
  static bool previousButtonLevel = HIGH; // negative logic
  static bool currentButtonLevel  = HIGH;  
  previousButtonLevel = currentButtonLevel;
  currentButtonLevel  = digitalRead(BUTTON_PIN); 
  return (currentButtonLevel == LOW && previousButtonLevel == HIGH); // falling edge
}

Mise en œuvre de clients applicatifs